rem ' hello.txt
sysgui = unt
open (sysgui)"X0"
bbjapi! = bbjapi()
sysgui! = bbjapi!.getSysGui()
window! = sysgui!.addWindow(100,100,225,75,"Hello",$00090003$,$$)
window!.setCallback(bbjapi!.ON_CLOSE,"EOJ")
hello! = window!.addButton(1,25,25,75,25,"Hello!")
hello!.focus()
hello!.setCallback(bbjapi!.ON_BUTTON_PUSH,"msgbox")
window!.setCallback(window!.ON_MOUSE_ENTER,"enter")
window!.setCallback(window!.ON_MOUSE_EXIT,"exit")
goodbye! = window!.addButton(2,125,25,75,25,"Goodbye!")
goodbye!.setCallback(bbjapi!.ON_BUTTON_PUSH,"eoj")
process_events
eoj:
  release
enter:
  window!.setBackColor(BBjColor.YELLOW)
return
exit:
  window!.setBackColor(null())
return
msgbox:
  info$ = "INFO(3,6)=" + info(3,6) + $0a$
  info$ = info$ + "INFO(6,0)=" + info(6,0)
  i = msgbox(info$,64,fnmode$(info(3,6)))
  hello!.focus()
return
def fnmode$(mode$)
  if mode$="0" then return "Fat Client"
  if mode$="1" then return "Thin Client"
  if mode$="2" then return "Java Applet"
  if mode$="3" then return "Java Web Start"
  if mode$="4" then return "JavaBBjBridge"
  if mode$="5" then return "BUI (Browser)"
  if mode$="6" then return "DWC (Browser)"
  if mode$="7" then return "Desktop App"
  if mode$="8" then return "WEBGUI (Browser)"
  return mode$
fnend