rem ' dagrid.txt
sysgui = unt
open (sysgui)"X0"
sysgui! = bbjapi().getSysGui()
window! = sysgui!.addWindow(100,100,500,450,"dagrid",$00090083$)
Grid! = Window!.addGrid(100,101,102,10,10,480,405,$81ca$,20,3)
Grid!.setRowHeight(25)
Grid!.setColumnWidth(0,100)
Grid!.setColumnWidth(1,180)
Grid!.setColumnWidth(2,180)
Grid!.setDefaultAlignment(Grid!.GRID_ALIGN_LEFT)
Grid!.setSelectionMode(Grid!.GRID_SELECT_ROW)
sql=sqlunt
sqlopen (sql)"ChileCompany"
sqlprep (sql)"select cust_num,first_name,last_name from customer"
sqlexec (sql)
dim sql$:sqltmpl(sql,ind=1)
sql$=sqlfetch(sql,ind=1)
text$="Query returned "+str(sql.rows_affected)+" rows."
print (sysgui)'plottext'(10,440,text$)
template$="CUST_NUM:C(6),FIRST_NAME:C(20),LAST_NAME:C(30)"
temp$=sendmsg(sysgui,100,80,-sql,template$)
dim event$:tmpl(sysgui),generic$:noticetpl(0,0)
repeat
  readrecord(sysgui,siz=10)event$
  e$=""; if pos(" 6 "=sys) then gosub event
  print e$," code=",event.code$," context=",str(event.context)," id=",str(event.id)," flags=",str(event.flags)," x=",str(event.x)," y=",str(event.y)
  if event.code$="N" then gosub notify
until event.code$="X"
eoj:
release
event:
  e$ = bbjapi().getSysGui().getLastEvent().toString()
  e$ = e$(1,pos("@"=e$)-1)
return
notify:
  generic$ = notice(sysgui,event.x)
  dim notice$:noticetpl(generic.objtype,event.flags)
  notice$ = generic$
  fields = pos($0a$=fattr(notice$,""),1,0)
  dim field$:"name["+str(fields)+"]:c(1*)"
  let field$=fattr(notice$,"")
  for field=1 to fields
    name$ = field.name$[field]
    info$ = fattr(notice$,name$,$$)
    print " ",name$,"=",
    if asc(info$)=1 then print field(notice$,name$), else print str(nfield(notice$,name$)),
  next field
  print ""
return